Trippy V0.17 diagnostics

Basic BT command sequence tests
--
-- do we get a \n in response to BT\n?
T: BT
R:
-- do we get a ?\n in response to a syntax error?
T: BT}
R: ?
-- do we get a zero in the accumulator?
T: BT?
R: =0
-- what about commands with errors after good text?
T: BT?}
R: =0?
-- is silent command terminator really silent?
T: BT?.BT?
R: =0=0
-- even where there is arbitrary junk between commands?
T: BT?. -junk- BT?
R: =0=0

Numeric Tests
--
-- can we accumulate and echo a number
T: BT@12345?
R: =12345
-- again (so we test all 10 digits)
T: BT@09876?
R: =9876
-- test maxint
T: BT@32767?
R: =32767
-- test minint
T: BT@32768?
R: =-32768
-- test rollover to -1
T: BT@65535?
R: =-1
-- test overflow
T: BT@65536?
R: ?

Test Access to Variables
--
-- check range of variable addressing allowed
T:BT@ABCDEFGHIJKLMNOPQRSTUVWXYZ
R:
-- store a value in variable S (S and T are guaranteed harmless)
T: BTS1234=
R:
-- read it back
T: BTS?
R: =1234
-- change it's value and check the result
T: BTS5678=S?
R: =5678

Test Arithmetic
--
-- add something to it and check the result
T: BTS4321+S?
R: =9999
-- subtract something and check 
T: BTS111-+S?
R: =9888
-- again and again
T: BTS11-+S1-+S?
R: =9876
-- now try shifting something into T
T: BTT1<T?
R: =256
-- now try shift and add
T: BTT1<T1+T?
R: =257
-- again
T: BTT1<2+T?
R: =258
-- do multiple assignment
T: BTS1=T2=
R:
-- check result
T: BTS?T?
R: =1=2
-- do it using autoincrement
T: BTS,3=
R:
-- check it
T: BTS?T?
R: =1=3
-- check it again with autoincrement
T: BTS??
R: =1=3
-- do multiple assignment
T: BTS4=5=S??
R: =4=5
-- check V0.15 variable numeric names
T: BT]19]6=20]7=S??
R: =6=7
-- do it again
T: BTS8=9=20]?19]?
R: =9=8
-- check illegal variable names
T: BT]1-]
R: ?
-- more
T: BT]98]
R: ?
-- plant value in start of bank 2
T: BT]48]351=
R:
-- plant value at end of bank 1, autoinc to read start of bank 2
T: BT]47]5678=9999?
R: =351
-- plant value at end of bank 2, show value of @
T: BT]95]9876=9999?
R: =9999
-- check again, bank 1-2 boundary
T: BT]47]??
R: =5678=351
-- check again, bank 2-1 boundary
T: BT]95]?5432?
R: =9876=5432
-- test sanity checks on V
T: BTV1-=V?
R: =0
T: BTV42=V?
R: =41
T: BTV20=V?V0=V?
R: =20=0
-- test sanity checks on L
T: BTL1-=L?
R: =0
T: BTL101=L?
R: =100
T: BTL50=L?L0=L?
R: =50=0
-- test V0.17 sanity checks on C (carrier frequency)
T: BTC9=C?
R: =10
T: BTC128=C?
R: =127
T: BTC50=C?
R: =50
-- test V0.16 sanity checks on D (an ugly affair!)
T: BTD0=D?
R: =261
T: BTD512=D?
R: =517
T: BTD10=D?
R: =266
-- test V0.16 sanity checks on 48] (an ugly affair!)
T: BT]48]256-=48]?
R: =11826
T: BT]48]1-=48]?
R: =351
-- test V0.16 sanity checks on 49] (an ugly affair!)
T: BT]49]256-=49]?
R: =11826
T: BT]49]1-=49]?
R: =351

Test Trippy Addressing
--
-- store a value in W and check it
T: BTW61=W?
R: =61
-- verify that this Trippy doesn't respond to wrong address
T: BT72W? BT
R:
-- verify that this Trippy does respond to new address
T: BT61W?
R: =61
-- verify that this Trippy still responds to address 0
T: BT00W?
R: =61
-- and verify that address 0 is the default
T: BTW?
R: =61

Test Trippy Timing (takes 1 second)
--
-- check untimed wait with no move in progress
T: BT!
R:
-- now wait a 1/5000 of a second
T: BT!1!
R:
-- now wait a 1/10 of a second
T: BT!500!
R:
-- now wait a 1 of a second
T: BT!5000!
R:

Test Trippy EEPROM interface
--
-- note:  EEPROM addresses are 7 bits, and there is a limit to the number
-- of times any block can be written, so we'll run the diagnostics using
-- block 127 (which is block 63 on the smaller 24C32 EEPROM chip).  Nobody
-- else should use that block.  We'll use the acceleration table as a
-- playground for testing the EEPROM.
--
-- setup an 8-word buffer guarded by 1010101010101010 patterns
T: BT]27]43690=1=2=4=8=16=32=64=128=43690=
R:
-- write it to block 127 of EEPROM, length 8
T: BTB127=28]8/
R:
     Sector 127 written
-- change buffer and change guard to 0101010101010101 pattern
T: BT]50]21845=0=0=0=0=0=0=0=0=21845=21845=21845=21845=21845=
R:
T: BT]64]43690=21845=43690=21845=43690=21845=43690=21845=
R:
     Buffer blanked out
-- write guard pattern to block 126
T: BTB126=59]12/
R:
     Alternate data written to block 126
-- try reading block 127 with length 12 from EEPROM
T: BTB127=51]12\
R:
     Sector 127 read
-- now verify sector 127!  (2 guard words, 8 data words, 4 words of 0 padding)
T: BT]50]?
R: =21845
T: BT]51]????
R: =1=2=4=8
T: BT]55]????
R: =16=32=64=128
T: BT]59]????
R: =0=0=0=0
T: BT]63]?
R: =21845
T: BT]64]????????
R: =-21846=21845=-21846=21845=-21846=21845=-21846=21845
     Sector 127 data and buffer padding words checked
-- now verify alternate block crossing RAM page boundary
T: BT]46]11826=11826=11826=11826=
R:
T: BTB126=47]2\
R:
T: BT]46]????
R: =11826=21845=21845=11826
     Sector 126 read and verified

Initialize For Motion
--
-- 1) Initialize 40 entry acceleration table
T: BT]27]250<104+79<67+59<53+49<46+
R:
T: BT]31]43<41+39<37+35<33+32<31+
R:
T: BT]35]43<41+39<37+35<33+32<31+
R:
T: BT]39]30<29+28<27+26<26+25<25+
R:
T: BT]43]24<24+23<23+22<22+22<21+
R:
-- Initialize half maximum velocity
T: BTV10=
R:
-- 2) Initialize power level
T: BTL90=
R:
-- 3) Record the Trippy's gear ratio (for 3:1 Trippy)
T: BTS2880=8640=
R:
-- 4) Set motion limits
T: BTM1080=1080-=1008=1008-=
R:

Done!
--